IN THIS ISSUE

AmiBroker 4.62.1 allows you to easily create and modify your indicators with few moves of a mouse. From now on you can build sophisticated indicators without any programming knowledge at all. The available (ready-to-use) indicators are listed in Charts tab of the Workspace window.

There is a video tutorial at: http://www.amibroker.net/video/dragdrop1.html that shows basic usage of new drag and drop functionality.

To remove the indicator, press Close button from the menu on the top right-hand side of the indicator pane (the menu will be displayed if you place the mouse cursor in the nearby). This menu allows you also to move the indicator pane up/down or maximize the pane.

How to overlay one indicator on another indicator.

These functions, when used in formula, allow you to change indicators' settings directly from Parameters window.


Param( (''name'', defvalue, min = 0, max = 100, step = 1, sincr = 0 )
Adds a new user-definable parameter, which will be accessible via Parameters dialog.

• "name" - defines parameter name that will be displayed in the parameters dialog
• default - defines default value of the parameter
• min, max - define minimum and maximum values of the parameter
• step - defines minimum increase of the parameter via slider in the Parameters dialog
• sincr - defines the increase of default value when more than one section of the same kind is inserted (dropped) onto the chart. For example if you insert the default Moving Average indicator into the same pane twice, the first moving average will be based on 15 periods, the other one on 25 (defvalue=15 + sincr=10)

ParamColor( ''name'', defaultcolor )
Adds a new user-definable color parameter, accessible via Parameters dialog.

• ''name'' - defines parameter name that will be displayed in the parameters dialog
• defaultcolor - defines default color value of the parameter

ParamColor function allows you to use colorCycle as a default value. When you use colorCycle parameter, default color cycles through red, blue, green, turquoise, gold, violet, bright green, dark yellow, when you insert your indicators into the same pane.


ParamStyle(''name'', default = styleLine, mask = maskDefault ) - allows to select the styles applied to the plot from the Parameters window. Apart from styles available in previous versions of AmiBroker, there are two new style constants:

• styleHidden - a combination of styleNoDraw | styleNoRescale
• styleDashed - dashed line

The list of available styles displayed in the Parameters window depends on the mask parameter.

• maskDefault - show thick, dashed, hidden, own scale styles (this is default mask for ParamStyle)
• maskAll - show all style flags
• maskPrice - show thick, hidden, own scale, candle, bar
• maskHistogram - show histogram, thick, hidden, own scale, area

ParamField(''name'', field = 3 ) - allows to pick the Price field for the indicator (field which is used to calculate values of the indicator). Function returns the array defined by field parameter. Default value = 3 returns Close array. The possible values of field parameter are:

• -1 - ParamField returns the values of the indicator that was inserted as a first one into the pane, or Close if no indicator was present
• 0 - returns Open array
• 1 - returns High array
• 2 - returns Low array
• 3 - returns Close array (default)
• 4 - returns Average array = (H+L+C)/3
• 5 - returns Volume array
• 6 - returns Open Interest array
• 7,8,9,.... - return values of indicators inserted into the pane.

ParamToggle(''name'',''values'',default=0 ) - function that allows to use boolean (Yes/No) parameters.

• ''name'' - the name of the parameter
• ''values'' - parameter values (separated with | character, e.g. "No|Yes" - first string represents false value and second string represents true value)
• default - default value of the parameter

_

Example:

The below indicator allows you to check how the parameters work in the custom code. You can change settings from Parameters dialog.

Buy = Cross(MACD(), Signal() );
Sell = Cross(Signal(), MACD() );

pricefield = ParamField("Price Field", 2);
Color = ParamColor("color",colorRed);
style = ParamStyle("style",styleLine,maskAll);
arrows = ParamToggle("Display arrows", "No|Yes",0);
Plot(pricefield,"My Indicator",Color,style);
if(arrows)
{
  PlotShapes(Buy*shapeUpArrow+Sell*shapeDownArrow,IIf(Buy,colorGreen,colorRed) );
}

 

Special functions: SECTION_BEGIN, _SECTION_END, _SECTION_NAME, _DEFAULT_NAME, _PARAM_VALUES explained
(for advanced users only)

These are new functions that are used by drag & drop mechanism. The most important pair is _SECTION_BEGIN("name") and _SECTION_END().

When you drop the formula onto chart pane AmiBroker appends the formula you have dragged at the end of existing chart formula and wraps inserted code with _SECTION_BEGIN("name") and _SECTION_END() markers:

So, if original formula looks as follows:

P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );

it will be transformed by AmiBroker to:

_SECTION_BEGIN("MA");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_SECTION_BEGIN/_SECTION_END markers allow AmiBroker to identify code parts and modify them later (for example remove individual sections). In addition to that sections provide the way to make sure that parameters having the same name in many code parts do not interfere each other. For example if you drop two moving averages the resulting code will look as follows:

_SECTION_BEGIN("MA");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_SECTION_BEGIN("MA1");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

Note that code and is parameter names are identical in both parts. Without sections the parameters with the same name will interfere. But thanks to uniquely named sections there is no conflict. This is so because AmiBroker identifies the parameter using section name AND parameter name, so if section names are unique then parameters can be uniquely identified. When dropping indicator AmiBroker automatically checks for already existing section names and auto-numbers similarly named sections to avoid conflicts. Section name also appears in the Parameter dialog:

Last but not least: you should NOT remove _SECTION_BEGIN / _SECTION_END markers from the formula. If you do, AmiBroker will not be able to recognize sections inside given formula any more and parameters with the same name will interfere with each other.

_SECTION_NAME is a function that just gives the name of the function (given in previous _SECTION_BEGIN call).

_DEFAULT_NAME is a function that returns the default name of plot. The default name consists of section name and comma separated list of values of numeric parameters defined in given section. For example in this code:

_SECTION_BEGIN("MA1");
P = ParamField("Price field");
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_DEFAULT_NAME will evaluate to "MA1(Close,15)" string.

_PARAM_VALUES works the same as _DEFAULT_NAME except that no section name is included (so only the list of parameter values is returned). So in above example _PARAM_VALUES will evaluate to "(Close, 15)" string.

Frequently Asked Questions about drag & drop functionality

A. When you double click the item in the chart tree AmiBroker creates new chart pane and generates the formula for it. It also gives it a name in the format of #Number SectionName. #Number is the consecutive chart formula number (AmiBroker stores custom formulas internally in the array that is numbered). Section name comes from AFL file name used to generate this chart. The numbering allows to distinguish between different formulas based on the same original indicator. Note that this may change in the future versions.

---

AmiBroker Tips newsletter. Issue 1/2004. Copyright (C)2004 AmiBroker.com. All back issues available from: http://www.amibroker.com/newsletter/