AmiBroker allows you to easily create and modify your indicators with a few moves of a mouse. From now on you can build sophisticated indicators without any programming knowledge at all. The available (ready-to-use) indicators are listed in the Charts tab of the Workspace window.

There is a video tutorial at: http://www.amibroker.net/video/dragdrop1.html that shows basic usage of new drag-and-drop functionality.

How to insert a new indicator.

To display a new indicator in a separate chart pane, just find the indicator in the Charts list (use Window -> Charts menu) and double-click the indicator name.

Alternatively, you can choose Insert from the context menu. As a result, a new indicator pane will be created and the Parameters dialog will be displayed. Here you can change the properties of the indicator (like color or periods). To accept the settings, press the OK button. (You will find the detailed description of the Parameters window below).

Example:
To insert an RSI pane - find the RSI indicator in the list, double-click the name, select the number of periods and color, then press OK.

How to overlay one indicator on another indicator.

To remove the indicator, press the Close button from the menu at the top right-hand side of the indicator pane (the menu will be displayed if you place the mouse cursor nearby). This menu also allows you to move the indicator pane up/down or maximize the pane.

How to remove the indicator plot from the pane.

These functions, when used in a formula, allow you to change indicators' settings directly from the Parameters window.


Param( ''name'', defvalue, min = 0, max = 100, step = 1, sincr = 0 )
Adds a new user-definable parameter, which will be accessible via the Parameters dialog.

• "name" - defines the parameter name that will be displayed in the Parameters dialog
• defvalue - defines the default value of the parameter
• min, max - define the minimum and maximum values of the parameter
• step - defines the minimum increment of the parameter via a slider in the Parameters dialog
• sincr - defines the increment of the default value when more than one section of the same kind is inserted (dropped) onto the chart. For example, if you insert the default Moving Average indicator into the same pane twice, the first moving average will be based on 15 periods, the other one on 25 (defvalue=15 + sincr=10)

ParamColor( ''name'', defaultcolor )
Adds a new user-definable color parameter, accessible via the Parameters dialog.

• ''name'' - defines the parameter name that will be displayed in the Parameters dialog
• defaultcolor - defines the default color value of the parameter

The ParamColor function allows you to use colorCycle as a default value. When you use the colorCycle parameter, the default color cycles through red, blue, green, turquoise, gold, violet, bright green, dark yellow when you insert your indicators into the same pane.


ParamStyle(''name'', defaultval = styleLine, mask = maskDefault ) - allows you to select the styles applied to the plot from the Parameters window. Apart from styles available in previous versions of AmiBroker, there are two new style constants:

• styleHidden - a combination of styleNoDraw | styleNoRescale
• styleDashed - dashed line

The list of available styles displayed in the Parameters window depends on the mask parameter.

• maskDefault - Shows thick, dashed, hidden, own scale styles (this is the default mask for ParamStyle)
• maskAll - Shows all style flags
• maskPrice - Shows thick, hidden, own scale, candle, bar
• maskHistogram - Shows histogram, thick, hidden, own scale, area

ParamField(''name'', field = 3 ) - allows you to pick the Price field for the indicator (the field that is used to calculate values of the indicator). The function returns the array defined by field parameter. Default value = 3 returns the Close array. The possible values of field parameter are:

• -1 - ParamField returns the values of the indicator that was inserted as a first one into the pane, or Close if no indicator was present
• 0 - returns the Open array
• 1 - returns the High array
• 2 - returns the Low array
• 3 - returns the Close array (default)
• 4 - returns the Average array = (H+L+C)/3
• 5 - returns the Volume array
• 6 - returns the Open Interest array
• 7,8,9,.... - return values of indicators inserted into the pane.

ParamToggle(''name'',''values'',defaultval=0 ) - a function that allows you to use boolean (Yes/No) parameters.

• ''name'' - the name of the parameter
• ''values'' - parameter values (separated by the | character, e.g. "No|Yes" - the first string represents the false value, and the second string represents the true value)
• defaultval - the default value of the parameter

_

Example:

The indicator below allows you to check how the parameters work in the custom code. You can change settings from the Parameters dialog.

Buy = Cross(MACD(), Signal() );
Sell = Cross(Signal(), MACD() );

pricefield = ParamField("Price Field", 2);
Color = ParamColor("color",colorRed);
style = ParamStyle("style",styleLine,maskAll);
arrows = ParamToggle("Display arrows", "No|Yes",0);
Plot(pricefield,"My Indicator",Color,style);
if(arrows)
{
  PlotShapes(Buy*shapeUpArrow+Sell*shapeDownArrow,IIf(Buy,colorGreen,colorRed) );
}

 

Special functions: SECTION_BEGIN, _SECTION_END, _SECTION_NAME, _DEFAULT_NAME, _PARAM_VALUES explained
(for advanced users only)

These are new functions that are used by the drag-and-drop mechanism. The most important pair is _SECTION_BEGIN("name") and _SECTION_END().

When you drop the formula onto a chart pane, AmiBroker appends the formula you have dragged at the end of the existing chart formula and wraps the inserted code with _SECTION_BEGIN("name") and _SECTION_END() markers:

So, if the original formula looks as follows:

P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );

it will be transformed by AmiBroker to:

_SECTION_BEGIN("MA");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_SECTION_BEGIN/_SECTION_END markers allow AmiBroker to identify code parts and modify them later (for example, remove individual sections). In addition to that, sections provide the way to make sure that parameters having the same name in many code parts do not interfere with each other. For example, if you drop two moving averages, the resulting code will look as follows:

_SECTION_BEGIN("MA");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_SECTION_BEGIN("MA1");
P = ParamField("Price field",-1);
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

Note that code and parameter names are identical in both parts. Without sections, parameters with the same name will interfere. But thanks to uniquely named sections, there is no conflict. This is so because AmiBroker identifies the parameter using both the section name AND the parameter name, so if section names are unique, then parameters can be uniquely identified. When dropping an indicator, AmiBroker automatically checks for already-existing section names and auto-numbers similarly named sections to avoid conflicts. The section name also appears in the Parameters dialog:

Last but not least, you should NOT remove _SECTION_BEGIN / _SECTION_END markers from the formula. If you do, AmiBroker will not be able to recognize sections inside a given formula anymore and parameters with the same name will interfere with each other.

_SECTION_NAME is a function that just gives the name of the section (given in the previous _SECTION_BEGIN call).

_DEFAULT_NAME is a function that returns the default name of the plot. The default name consists of the section name and a comma-separated list of values of numeric parameters defined in the given section. For example, in the following code:

_SECTION_BEGIN("MA1");
P = ParamField("Price field");
Periods = Param("Periods", 15, 2, 200, 1, 10 );
Plot( MA( P, Periods ), _DEFAULT_NAME(), ParamColor( "Color", colorCycle ), ParamStyle("Style") );
_SECTION_END();

_DEFAULT_NAME will evaluate to "MA1(Close,15)".

_PARAM_VALUES works the same as _DEFAULT_NAME except that no section name is included (so only the list of parameter values is returned). So, in the above example, _PARAM_VALUES will evaluate to "(Close, 15)".

Frequently Asked Questions about drag-and-drop functionality

Q. What is the difference between Insert and Insert Linked options in the chart menu?

A. Insert command internally creates a copy of the original formula file and places such a copy into a hidden drag-and-drop folder, so the original formula will not be affected by subsequent editing or overlaying other indicators onto it. Double-clicking a formula name in the chart tree is equivalent to choosing the Insert command from the menu. On the other hand, the Insert Linked command does not create a copy of the formula. Instead, it creates a new chart pane that directly links to the original formula. This way, subsequent editing and/or overlaying other indicators will modify the original formula.